Contract

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474

// SPDX-License-Identifier: MIT
pragma solidity 0.8.28;

/*

      ██╗   ██╗███████╗███████╗████████╗███████╗██╗
      ╚██╗ ██╔╝██╔════╝██╔════╝╚══██╔══╝██╔════╝██║
       ╚████╔╝ █████╗  █████╗     ██║   █████╗  ██║
        ╚██╔╝  ██╔══╝  ██╔══╝     ██║   ██╔══╝  ██║
         ██║   ███████╗███████╗   ██║   ██║     ██║
         ╚═╝   ╚══════╝╚══════╝   ╚═╝   ╚═╝     ╚═╝

      S A F E   L A U N C H E R
      ─────────────────────────

  Permissionless one-transaction token launcher.
  No owner, no admin key, no upgrade path.

  Docs:   https://robinhood.yeetfi.xyz/docs

*/

interface IERC20Min {
    function approve(address spender, uint256 amount) external returns (bool);
    function transfer(address to, uint256 amount) external returns (bool);
    function balanceOf(address account) external view returns (uint256);
}
interface IWETH9 {
    function deposit() external payable;
}

interface IUniswapV3PoolState {
    function slot0()
        external
        view
        returns (
            uint160 sqrtPriceX96,
            int24 tick,
            uint16 observationIndex,
            uint16 observationCardinality,
            uint16 observationCardinalityNext,
            uint8 feeProtocol,
            bool unlocked
        );

}

interface ISwapRouter02 {
    struct ExactInputSingleParams {
        address tokenIn;
        address tokenOut;
        uint24 fee;
        address recipient;
        uint256 amountIn;
        uint256 amountOutMinimum;
        uint160 sqrtPriceLimitX96;
    }

    function exactInputSingle(ExactInputSingleParams calldata params)
        external
        payable
        returns (uint256 amountOut);
}

interface INonfungiblePositionManager {
    function createAndInitializePoolIfNecessary(
        address token0,
        address token1,
        uint24 fee,
        uint160 sqrtPriceX96
    ) external payable returns (address pool);

    struct MintParams {
        address token0;
        address token1;
        uint24 fee;
        int24 tickLower;
        int24 tickUpper;
        uint256 amount0Desired;
        uint256 amount1Desired;
        uint256 amount0Min;
        uint256 amount1Min;
        address recipient;
        uint256 deadline;
    }

    function mint(MintParams calldata params)
        external
        payable
        returns (uint256 tokenId, uint128 liquidity, uint256 amount0, uint256 amount1);

    struct CollectParams {
        uint256 tokenId;
        address recipient;
        uint128 amount0Max;
        uint128 amount1Max;
    }

    function collect(CollectParams calldata params)
        external
        payable
        returns (uint256 amount0, uint256 amount1);
}

contract YeetFiLaunchToken {
    string public name;
    string public symbol;
    uint8 public constant decimals = 18;
    uint256 public immutable totalSupply;
    address public immutable owner;

    mapping(address => uint256) public balanceOf;
    mapping(address => mapping(address => uint256)) public allowance;

    event Transfer(address indexed from, address indexed to, uint256 value);
    event Approval(address indexed owner, address indexed spender, uint256 value);
    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    constructor(string memory _name, string memory _symbol, uint256 _supply, address _mintTo) {
        name = _name;
        symbol = _symbol;
        totalSupply = _supply;
        balanceOf[_mintTo] = _supply;
        emit Transfer(address(0), _mintTo, _supply);

        owner = address(0);
        emit OwnershipTransferred(address(0), _mintTo);
        emit OwnershipTransferred(_mintTo, address(0));
    }

    function approve(address spender, uint256 amount) external returns (bool) {
        allowance[msg.sender][spender] = amount;
        emit Approval(msg.sender, spender, amount);
        return true;
    }

    function transfer(address to, uint256 amount) external returns (bool) {
        return _transfer(msg.sender, to, amount);
    }

    function transferFrom(address from, address to, uint256 amount) external returns (bool) {
        uint256 a = allowance[from][msg.sender];
        if (a != type(uint256).max) {
            require(a >= amount, "allowance");
            allowance[from][msg.sender] = a - amount;
        }
        return _transfer(from, to, amount);
    }

    function _transfer(address from, address to, uint256 amount) internal returns (bool) {
        require(balanceOf[from] >= amount, "balance");
        require(to != address(0), "to zero");
        unchecked {
            balanceOf[from] -= amount;
            balanceOf[to] += amount;
        }
        emit Transfer(from, to, amount);
        return true;
    }
}

contract yeetFiSafeLauncher {
    enum Venue {
        UNISWAP_V3,
        SUSHISWAP_V3
    }

    enum Preset {
        MC_0_5_ETH,
        MC_1_ETH,
        MC_2_ETH,
        MC_5_ETH
    }

    struct DevBuy {
        address recipient;
        uint256 amountIn; // in WETH wei (18-dec)
        uint256 minOut;
    }

    struct Position {
        address token;
        address pool;
        address creator;
        bool tokenIsToken0;
    }

    address public immutable QUOTE;
    address public immutable UNI_POSITION_MANAGER;
    address public immutable UNI_SWAP_ROUTER;
    address public immutable SUSHI_POSITION_MANAGER;
    address public immutable SUSHI_SWAP_ROUTER;
    address public constant FEE_RECIPIENT = 0x8ab3914eEEE3965f3d680703196e92efcBF3fAbD;
    uint256 public constant LAUNCH_FEE = 0.002 ether;
    uint256 public constant TOTAL_SUPPLY = 1_000_000_000e18;
    uint24 public constant POOL_FEE = 10_000; // 1%
    int24 public constant TICK_SPACING = 200;
    uint256 public constant CREATOR_SHARE_BPS = 7_000;
    uint256 internal constant BPS = 10_000;
    uint160 public constant VANITY_SUFFIX = 0x5afe;
    uint160 internal constant VANITY_MASK = 0xffff;
    int24 internal constant MAX_TICK = 887272; // Uniswap V3 TickMath.MAX_TICK
    uint160 internal constant SQRT_MC_0_5 = 1771595571142957102961017;
    uint160 internal constant SQRT_MC_1 = 2505414483750479311864138;
    uint160 internal constant SQRT_MC_2 = 3543191142285914205922034;
    uint160 internal constant SQRT_MC_5 = 5602277097478613991873193;
    mapping(Venue => mapping(uint256 => Position)) public positions;
    error PoolPriceMismatch(uint160 expected, uint160 actual);
    error FeeNotPaid(uint256 sent, uint256 required);
    error SaltNot5afe(address wouldBe);
    error FeeTransferFailed();
    error RefundFailed();
    error BadDevBuy();
    error QuoteApproveFailed();
    error UnknownPosition(uint256 tokenId);

    event Yeeted(
        address indexed token,
        address indexed pool,
        address indexed deployer,
        uint256 tokenId,
        Preset preset,
        bool tokenIsToken0,
        Venue venue
    );

    event DevBought(
        address indexed token,
        address indexed recipient,
        uint256 amountIn,
        uint256 amountOut
    );

    event FeePaid(address indexed payer, address indexed recipient, uint256 amount);

    event FeesCollected(
        Venue indexed venue,
        uint256 indexed tokenId,
        address indexed token,
        uint256 tokenFees,
        uint256 tokenSold,
        uint256 quoteTotal,
        uint256 toCreator,
        uint256 toTreasury
    );

    constructor(
        address _quote,
        address _uniPositionManager,
        address _uniSwapRouter,
        address _sushiPositionManager,
        address _sushiSwapRouter
    ) {
        require(
            _quote != address(0) && _uniPositionManager != address(0)
                && _uniSwapRouter != address(0) && _sushiPositionManager != address(0)
                && _sushiSwapRouter != address(0),
            "zero"
        );
        QUOTE = _quote;
        UNI_POSITION_MANAGER = _uniPositionManager;
        UNI_SWAP_ROUTER = _uniSwapRouter;
        SUSHI_POSITION_MANAGER = _sushiPositionManager;
        SUSHI_SWAP_ROUTER = _sushiSwapRouter;
    }
    function predictTokenAddress(
        address deployer,
        bytes32 salt,
        string calldata name_,
        string calldata symbol_
    ) external view returns (address) {
        return address(
            uint160(
                uint256(
                    keccak256(
                        abi.encodePacked(
                            bytes1(0xff),
                            address(this),
                            keccak256(abi.encode(deployer, salt)),
                            initCodeHash(name_, symbol_)
                        )
                    )
                )
            )
        );
    }

    function initCodeHash(
        string calldata name_,
        string calldata symbol_
    ) public view returns (bytes32) {
        return keccak256(
            abi.encodePacked(
                type(YeetFiLaunchToken).creationCode,
                abi.encode(name_, symbol_, TOTAL_SUPPLY, address(this))
            )
        );
    }

    function yeet(
        string calldata name_,
        string calldata symbol_,
        Preset preset,
        bytes32 salt,
        DevBuy[] calldata devBuys,
        Venue venue
    ) external payable returns (address token, address pool, uint256 tokenId) {
        (address npm, address router) = _venueAddrs(venue);
        uint256 devTotal;
        for (uint256 i = 0; i < devBuys.length; i++) {
            if (devBuys[i].recipient == address(0) || devBuys[i].amountIn == 0) revert BadDevBuy();
            devTotal += devBuys[i].amountIn;
        }
        uint256 required = LAUNCH_FEE + devTotal;
        if (msg.value < required) revert FeeNotPaid(msg.value, required);
        token = address(
            new YeetFiLaunchToken{salt: keccak256(abi.encode(msg.sender, salt))}(
                name_, symbol_, TOTAL_SUPPLY, address(this)
            )
        );
        if (uint160(token) & VANITY_MASK != VANITY_SUFFIX) revert SaltNot5afe(token);

        bool tokenIsToken0 = token < QUOTE;
        (address token0, address token1) = tokenIsToken0 ? (token, QUOTE) : (QUOTE, token);
        uint160 sqrtAsToken0 = _presetSqrtPriceX96(preset);
        uint160 sqrtPriceX96 = tokenIsToken0
            ? sqrtAsToken0
            : uint160((uint256(1) << 192) / uint256(sqrtAsToken0)); // sqrt(1/P) = 2^192 / S

        pool = INonfungiblePositionManager(npm)
            .createAndInitializePoolIfNecessary(token0, token1, POOL_FEE, sqrtPriceX96);
        (uint160 poolSqrt, int24 curTick, , , , , ) = IUniswapV3PoolState(pool).slot0();
        if (poolSqrt != sqrtPriceX96) revert PoolPriceMismatch(sqrtPriceX96, poolSqrt);
        int24 maxUsable = (MAX_TICK / TICK_SPACING) * TICK_SPACING;

        int24 tickLower;
        int24 tickUpper;
        uint256 amount0Desired;
        uint256 amount1Desired;
        if (tokenIsToken0) {
            tickLower = _ceilSpacing(curTick + 1, TICK_SPACING);
            tickUpper = maxUsable;
            amount0Desired = TOTAL_SUPPLY;
        } else {
            tickLower = -maxUsable;
            tickUpper = _floorSpacing(curTick, TICK_SPACING);
            amount1Desired = TOTAL_SUPPLY;
        }
        require(IERC20Min(token).approve(npm, TOTAL_SUPPLY), "approve failed");
        (tokenId, , , ) = INonfungiblePositionManager(npm).mint(
            INonfungiblePositionManager.MintParams({
                token0: token0,
                token1: token1,
                fee: POOL_FEE,
                tickLower: tickLower,
                tickUpper: tickUpper,
                amount0Desired: amount0Desired,
                amount1Desired: amount1Desired,
                amount0Min: 0,
                amount1Min: 0,
                recipient: address(this),
                deadline: block.timestamp
            })
        );
        positions[venue][tokenId] =
            Position({token: token, pool: pool, creator: msg.sender, tokenIsToken0: tokenIsToken0});
        if (devBuys.length > 0) {
            IWETH9(QUOTE).deposit{value: devTotal}();
            if (!IERC20Min(QUOTE).approve(router, devTotal)) revert QuoteApproveFailed();
            for (uint256 i = 0; i < devBuys.length; i++) {
                uint256 amountOut = ISwapRouter02(router).exactInputSingle(
                    ISwapRouter02.ExactInputSingleParams({
                        tokenIn: QUOTE,
                        tokenOut: token,
                        fee: POOL_FEE,
                        recipient: devBuys[i].recipient,
                        amountIn: devBuys[i].amountIn,
                        amountOutMinimum: devBuys[i].minOut,
                        sqrtPriceLimitX96: 0
                    })
                );
                emit DevBought(token, devBuys[i].recipient, devBuys[i].amountIn, amountOut);
            }
            if (!IERC20Min(QUOTE).approve(router, 0)) revert QuoteApproveFailed();
        }

        uint256 leftover = IERC20Min(token).balanceOf(address(this));
        if (leftover > 0) {
            require(IERC20Min(token).transfer(msg.sender, leftover), "dust transfer failed");
        }

        emit Yeeted(token, pool, msg.sender, tokenId, preset, tokenIsToken0, venue);
        (bool feeOk, ) = FEE_RECIPIENT.call{value: LAUNCH_FEE}("");
        if (!feeOk) revert FeeTransferFailed();
        emit FeePaid(msg.sender, FEE_RECIPIENT, LAUNCH_FEE);

        uint256 refund = msg.value - required;
        if (refund > 0) {
            (bool refundOk, ) = msg.sender.call{value: refund}("");
            if (!refundOk) revert RefundFailed();
        }
    }
    function collect(Venue venue, uint256 tokenId)
        external
        returns (uint256 toCreator, uint256 toTreasury)
    {
        (address npm, address router) = _venueAddrs(venue);
        Position memory p = positions[venue][tokenId];
        if (p.token == address(0)) revert UnknownPosition(tokenId);

        INonfungiblePositionManager(npm).collect(
            INonfungiblePositionManager.CollectParams({
                tokenId: tokenId,
                recipient: address(this),
                amount0Max: type(uint128).max,
                amount1Max: type(uint128).max
            })
        );
        uint256 tokenBal = IERC20Min(p.token).balanceOf(address(this));
        uint256 sold;
        if (tokenBal > 0) {
            if (!IERC20Min(p.token).approve(router, tokenBal)) revert QuoteApproveFailed();
            sold = ISwapRouter02(router).exactInputSingle(
                ISwapRouter02.ExactInputSingleParams({
                    tokenIn: p.token,
                    tokenOut: QUOTE,
                    fee: POOL_FEE,
                    recipient: address(this),
                    amountIn: tokenBal,
                    amountOutMinimum: 0,
                    sqrtPriceLimitX96: 0
                })
            );
            if (!IERC20Min(p.token).approve(router, 0)) revert QuoteApproveFailed();
        }
        uint256 quoteTotal = IERC20Min(QUOTE).balanceOf(address(this));
        if (quoteTotal > 0) {
            toCreator = (quoteTotal * CREATOR_SHARE_BPS) / BPS;
            toTreasury = quoteTotal - toCreator;
            if (toCreator > 0) {
                require(IERC20Min(QUOTE).transfer(p.creator, toCreator), "creator transfer");
            }
            require(IERC20Min(QUOTE).transfer(FEE_RECIPIENT, toTreasury), "treasury transfer");
        }

        uint256 tokenLeft = IERC20Min(p.token).balanceOf(address(this));
        emit FeesCollected(
            venue, tokenId, p.token, tokenBal, tokenBal - tokenLeft, quoteTotal, toCreator, toTreasury
        );
    }

    function _venueAddrs(Venue venue) internal view returns (address npm, address router) {
        return venue == Venue.UNISWAP_V3
            ? (UNI_POSITION_MANAGER, UNI_SWAP_ROUTER)
            : (SUSHI_POSITION_MANAGER, SUSHI_SWAP_ROUTER);
    }
    function _presetSqrtPriceX96(Preset p) internal pure returns (uint160) {
        if (p == Preset.MC_0_5_ETH) return SQRT_MC_0_5;
        if (p == Preset.MC_1_ETH) return SQRT_MC_1;
        if (p == Preset.MC_2_ETH) return SQRT_MC_2;
        return SQRT_MC_5;
    }
    function _floorSpacing(int24 t, int24 s) internal pure returns (int24) {
        int24 q = t / s;
        if (t < 0 && t % s != 0) q -= 1;
        return q * s;
    }

    function _ceilSpacing(int24 t, int24 s) internal pure returns (int24) {
        int24 q = t / s;
        if (t > 0 && t % s != 0) q += 1;
        return q * s;
    }
}